DOUBLE PRECISION FUNCTION iau_EECT00 ( DATE1, DATE2 )
*+
* - - - - - - - - - - -
* i a u _ E E C T 0 0
* - - - - - - - - - - -
*
* Equation of the equinoxes complementary terms, consistent with
* IAU 2000 resolutions.
*
* This routine is part of the International Astronomical Union's
* SOFA (Standards of Fundamental Astronomy) software collection.
*
* Status: canonical model.
*
* Given:
* DATE1,DATE2 d TT as a 2-part Julian Date (Note 1)
*
* Returned:
* iau_EECT00 d complementary terms (Note 2)
*
* Notes:
*
* 1) The TT date DATE1+DATE2 is a Julian Date, apportioned in any
* convenient way between the two arguments. For example,
* JD(TT)=2450123.7 could be expressed in any of these ways,
* among others:
*
* DATE1 DATE2
*
* 2450123.7D0 0D0 (JD method)
* 2451545D0 -1421.3D0 (J2000 method)
* 2400000.5D0 50123.2D0 (MJD method)
* 2450123.5D0 0.2D0 (date & time method)
*
* The JD method is the most natural and convenient to use in
* cases where the loss of several decimal digits of resolution
* is acceptable. The J2000 method is best matched to the way
* the argument is handled internally and will deliver the
* optimum resolution. The MJD method and the date & time methods
* are both good compromises between resolution and convenience.
*
* 2) The "complementary terms" are part of the equation of the
* equinoxes (EE), classically the difference between apparent and
* mean Sidereal Time:
*
* GAST = GMST + EE
*
* with:
*
* EE = dpsi * cos(eps)
*
* where dpsi is the nutation in longitude and eps is the obliquity
* of date. However, if the rotation of the Earth were constant in
* an inertial frame the classical formulation would lead to apparent
* irregularities in the UT1 timescale traceable to side-effects of
* precession-nutation. In order to eliminate these effects from
* UT1, "complementary terms" were introduced in 1994 (IAU, 1994) and
* took effect from 1997 (Capitaine and Gontier, 1993):
*
* GAST = GMST + CT + EE
*
* By convention, the complementary terms are included as part of the
* equation of the equinoxes rather than as part of the mean Sidereal
* Time. This slightly compromises the "geometrical" interpretation
* of mean sidereal time but is otherwise inconsequential.
*
* The present routine computes CT in the above expression,
* compatible with IAU 2000 resolutions (Capitaine et al., 2002, and
* IERS Conventions 2003).
*
* Called:
* iau_FAL03 mean anomaly of the Moon
* iau_FALP03 mean anomaly of the Sun
* iau_FAF03 mean argument of the latitude of the Moon
* iau_FAD03 mean elongation of the Moon from the Sun
* iau_FAOM03 mean longitude of the Moon's ascending node
* iau_FAVE03 mean longitude of Venus
* iau_FAE03 mean longitude of Earth
* iau_FAPA03 general accumulated precession in longitude
*
* References:
*
* Capitaine, N. & Gontier, A.-M., Astron.Astrophys., 275,
* 645-650 (1993)
*
* Capitaine, N., Wallace, P.T. and McCarthy, D.D., "Expressions to
* implement the IAU 2000 definition of UT1", Astron.Astrophys.,
* 406, 1135-1149 (2003)
*
* IAU Resolution C7, Recommendation 3 (1994)
*
* McCarthy, D. D., Petit, G. (eds.), IERS Conventions (2003),
* IERS Technical Note No. 32, BKG (2004)
*
* This revision: 2017 October 23
*
* SOFA release 2021-05-12
*
* Copyright (C) 2021 IAU SOFA Board. See notes at end.
*
*-----------------------------------------------------------------------
IMPLICIT NONE
DOUBLE PRECISION DATE1, DATE2
* Arcseconds to radians
DOUBLE PRECISION DAS2R
PARAMETER ( DAS2R = 4.848136811095359935899141D-6 )
* Reference epoch (J2000.0), JD
DOUBLE PRECISION DJ00
PARAMETER ( DJ00 = 2451545D0 )
* Days per Julian century
DOUBLE PRECISION DJC
PARAMETER ( DJC = 36525D0 )
* Time since J2000.0, in Julian centuries
DOUBLE PRECISION T
* Miscellaneous
INTEGER I, J
DOUBLE PRECISION A, S0, S1
DOUBLE PRECISION iau_FAL03, iau_FALP03, iau_FAF03,
: iau_FAD03, iau_FAOM03, iau_FAVE03, iau_FAE03,
: iau_FAPA03
* Fundamental arguments
DOUBLE PRECISION FA(14)
* -----------------------------------------
* The series for the EE complementary terms
* -----------------------------------------
* Number of terms in the series
INTEGER NE0, NE1
PARAMETER ( NE0=33, NE1=1 )
* Coefficients of l,l',F,D,Om,LVe,LE,pA
INTEGER KE0 ( 8, NE0 ),
: KE1 ( 8, NE1 )
* Sine and cosine coefficients
DOUBLE PRECISION SE0 ( 2, NE0 ),
: SE1 ( 2, NE1 )
* Argument coefficients for t^0
DATA ( ( KE0(I,J), I=1,8), J=1,10 ) /
: 0, 0, 0, 0, 1, 0, 0, 0,
: 0, 0, 0, 0, 2, 0, 0, 0,
: 0, 0, 2, -2, 3, 0, 0, 0,
: 0, 0, 2, -2, 1, 0, 0, 0,
: 0, 0, 2, -2, 2, 0, 0, 0,
: 0, 0, 2, 0, 3, 0, 0, 0,
: 0, 0, 2, 0, 1, 0, 0, 0,
: 0, 0, 0, 0, 3, 0, 0, 0,
: 0, 1, 0, 0, 1, 0, 0, 0,
: 0, 1, 0, 0, -1, 0, 0, 0 /
DATA ( ( KE0(I,J), I=1,8), J=11,20 ) /
: 1, 0, 0, 0, -1, 0, 0, 0,
: 1, 0, 0, 0, 1, 0, 0, 0,
: 0, 1, 2, -2, 3, 0, 0, 0,
: 0, 1, 2, -2, 1, 0, 0, 0,
: 0, 0, 4, -4, 4, 0, 0, 0,
: 0, 0, 1, -1, 1, -8, 12, 0,
: 0, 0, 2, 0, 0, 0, 0, 0,
: 0, 0, 2, 0, 2, 0, 0, 0,
: 1, 0, 2, 0, 3, 0, 0, 0,
: 1, 0, 2, 0, 1, 0, 0, 0 /
DATA ( ( KE0(I,J), I=1,8), J=21,30 ) /
: 0, 0, 2, -2, 0, 0, 0, 0,
: 0, 1, -2, 2, -3, 0, 0, 0,
: 0, 1, -2, 2, -1, 0, 0, 0,
: 0, 0, 0, 0, 0, 8,-13, -1,
: 0, 0, 0, 2, 0, 0, 0, 0,
: 2, 0, -2, 0, -1, 0, 0, 0,
: 1, 0, 0, -2, 1, 0, 0, 0,
: 0, 1, 2, -2, 2, 0, 0, 0,
: 1, 0, 0, -2, -1, 0, 0, 0,
: 0, 0, 4, -2, 4, 0, 0, 0 /
DATA ( ( KE0(I,J), I=1,8), J=31,NE0 ) /
: 0, 0, 2, -2, 4, 0, 0, 0,
: 1, 0, -2, 0, -3, 0, 0, 0,
: 1, 0, -2, 0, -1, 0, 0, 0 /
* Argument coefficients for t^1
DATA ( ( KE1(I,J), I=1,8), J=1,NE1 ) /
: 0, 0, 0, 0, 1, 0, 0, 0 /
* Sine and cosine coefficients for t^0
DATA ( ( SE0(I,J), I=1,2), J = 1, 10 ) /
: +2640.96D-6, -0.39D-6,
: +63.52D-6, -0.02D-6,
: +11.75D-6, +0.01D-6,
: +11.21D-6, +0.01D-6,
: -4.55D-6, +0.00D-6,
: +2.02D-6, +0.00D-6,
: +1.98D-6, +0.00D-6,
: -1.72D-6, +0.00D-6,
: -1.41D-6, -0.01D-6,
: -1.26D-6, -0.01D-6 /
DATA ( ( SE0(I,J), I=1,2), J = 11, 20 ) /
: -0.63D-6, +0.00D-6,
: -0.63D-6, +0.00D-6,
: +0.46D-6, +0.00D-6,
: +0.45D-6, +0.00D-6,
: +0.36D-6, +0.00D-6,
: -0.24D-6, -0.12D-6,
: +0.32D-6, +0.00D-6,
: +0.28D-6, +0.00D-6,
: +0.27D-6, +0.00D-6,
: +0.26D-6, +0.00D-6 /
DATA ( ( SE0(I,J), I=1,2), J = 21, 30 ) /
: -0.21D-6, +0.00D-6,
: +0.19D-6, +0.00D-6,
: +0.18D-6, +0.00D-6,
: -0.10D-6, +0.05D-6,
: +0.15D-6, +0.00D-6,
: -0.14D-6, +0.00D-6,
: +0.14D-6, +0.00D-6,
: -0.14D-6, +0.00D-6,
: +0.14D-6, +0.00D-6,
: +0.13D-6, +0.00D-6 /
DATA ( ( SE0(I,J), I=1,2), J = 31, NE0 ) /
: -0.11D-6, +0.00D-6,
: +0.11D-6, +0.00D-6,
: +0.11D-6, +0.00D-6 /
* Sine and cosine coefficients for t^1
DATA ( ( SE1(I,J), I=1,2), J = 1, NE1 ) /
: -0.87D-6, +0.00D-6 /
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
* Interval between fundamental epoch J2000.0 and current date (JC).
T = ( ( DATE1-DJ00 ) + DATE2 ) / DJC
* Fundamental Arguments (from IERS Conventions 2003)
* Mean anomaly of the Moon.
FA(1) = iau_FAL03 ( T )
* Mean anomaly of the Sun.
FA(2) = iau_FALP03 ( T )
* Mean longitude of the Moon minus that of the ascending node.
FA(3) = iau_FAF03 ( T )
* Mean elongation of the Moon from the Sun.
FA(4) = iau_FAD03 ( T )
* Mean longitude of the ascending node of the Moon.
FA(5) = iau_FAOM03 ( T )
* Mean longitude of Venus.
FA(6) = iau_FAVE03 ( T )
* Mean longitude of Earth.
FA(7) = iau_FAE03 ( T )
* General precession in longitude.
FA(8) = iau_FAPA03 ( T )
* Evaluate the EE complementary terms.
S0 = 0D0
S1 = 0D0
DO 2 I = NE0,1,-1
A = 0D0
DO 1 J=1,8
A = A + DBLE(KE0(J,I))*FA(J)
1 CONTINUE
S0 = S0 + ( SE0(1,I)*SIN(A) + SE0(2,I)*COS(A) )
2 CONTINUE
DO 4 I = NE1,1,-1
A = 0D0
DO 3 J=1,8
A = A + DBLE(KE1(J,I))*FA(J)
3 CONTINUE
S1 = S1 + ( SE1(1,I)*SIN(A) + SE1(2,I)*COS(A) )
4 CONTINUE
iau_EECT00 = ( S0 + S1 * T ) * DAS2R
* Finished.
*+----------------------------------------------------------------------
*
* Copyright (C) 2021
* Standards Of Fundamental Astronomy Board
* of the International Astronomical Union.
*
* =====================
* SOFA Software License
* =====================
*
* NOTICE TO USER:
*
* BY USING THIS SOFTWARE YOU ACCEPT THE FOLLOWING SIX TERMS AND
* CONDITIONS WHICH APPLY TO ITS USE.
*
* 1. The Software is owned by the IAU SOFA Board ("SOFA").
*
* 2. Permission is granted to anyone to use the SOFA software for any
* purpose, including commercial applications, free of charge and
* without payment of royalties, subject to the conditions and
* restrictions listed below.
*
* 3. You (the user) may copy and distribute SOFA source code to others,
* and use and adapt its code and algorithms in your own software,
* on a world-wide, royalty-free basis. That portion of your
* distribution that does not consist of intact and unchanged copies
* of SOFA source code files is a "derived work" that must comply
* with the following requirements:
*
* a) Your work shall be marked or carry a statement that it
* (i) uses routines and computations derived by you from
* software provided by SOFA under license to you; and
* (ii) does not itself constitute software provided by and/or
* endorsed by SOFA.
*
* b) The source code of your derived work must contain descriptions
* of how the derived work is based upon, contains and/or differs
* from the original SOFA software.
*
* c) The names of all routines in your derived work shall not
* include the prefix "iau" or "sofa" or trivial modifications
* thereof such as changes of case.
*
* d) The origin of the SOFA components of your derived work must
* not be misrepresented; you must not claim that you wrote the
* original software, nor file a patent application for SOFA
* software or algorithms embedded in the SOFA software.
*
* e) These requirements must be reproduced intact in any source
* distribution and shall apply to anyone to whom you have
* granted a further right to modify the source code of your
* derived work.
*
* Note that, as originally distributed, the SOFA software is
* intended to be a definitive implementation of the IAU standards,
* and consequently third-party modifications are discouraged. All
* variations, no matter how minor, must be explicitly marked as
* such, as explained above.
*
* 4. You shall not cause the SOFA software to be brought into
* disrepute, either by misuse, or use for inappropriate tasks, or
* by inappropriate modification.
*
* 5. The SOFA software is provided "as is" and SOFA makes no warranty
* as to its use or performance. SOFA does not and cannot warrant
* the performance or results which the user may obtain by using the
* SOFA software. SOFA makes no warranties, express or implied, as
* to non-infringement of third party rights, merchantability, or
* fitness for any particular purpose. In no event will SOFA be
* liable to the user for any consequential, incidental, or special
* damages, including any lost profits or lost savings, even if a
* SOFA representative has been advised of such damages, or for any
* claim by any third party.
*
* 6. The provision of any version of the SOFA software under the terms
* and conditions specified herein does not imply that future
* versions will also be made available under the same terms and
* conditions.
*
* In any published work or commercial product which uses the SOFA
* software directly, acknowledgement (see www.iausofa.org) is
* appreciated.
*
* Correspondence concerning SOFA software should be addressed as
* follows:
*
* By email: sofa@ukho.gov.uk
* By post: IAU SOFA Center
* HM Nautical Almanac Office
* UK Hydrographic Office
* Admiralty Way, Taunton
* Somerset, TA1 2DN
* United Kingdom
*
*-----------------------------------------------------------------------
END